Rumus Excel FIND merupakan satu dari beberapa fungsi yang akan pada kategori atau kelompok Fungsi Text. Ada beberapa rumus menarik pada kategori ini dan dua diantaranya adalah FIND serta SEARCH.
Dua rumus ini memang menarik untuk dibahas karena memiliki fungsi serta hasil yang sangat mirip bahkan hampir dikatakan sama.
Tapi sebenarnya ada beberapa perbedaan dari dua rumus Excel ini. Adhwebsite.com akan membahas beberapa hal terkait dengan rumus Excel FIND termasuk perbedaan dengan rumus SEARCH.
Secara umum fungsi rumus FIND dalam Excel memang terkait dengan pencarian teks, huruf atau angka. Pencarian ini bisa digunakan untuk beberapa keperluan. Misalnya mengubah teks tertentu dengan posisi berbeda dan lain – lain.
Terkait dengan contoh serta cara menggunakan kita juga akan bahas beberapa konsep pengolahan teks yang memang cocok untuk menggunakan rumus Excel FIND.
Tapi sebelum itu mari kita bahas secara detail terkait dengan fungsi rumus FIND dalam Microsoft Excel.
Fungsi Rumus Excel FIND
Secara umum rumus FIND dalam Exel fungsinya terkait dengan pencarian teks seperti yang disebutkan diatas.
Rumus FIND akan mencari posisi karakter yang ada pada deret sebuah string yang telah dibuat sebelumnya.
Misalnya kita akan mencari posisi huruf "a" pada deret kalimat "anda dan saya adalah adhwebsite.com" maka hasil yang akan ditampilkan adalah angka 1.
Angka 1 tersebut merupakan posisi huruf "a" pada bagian paling awal deret kalimat. Dalam prosesnya nanti akan ada rumus FIND bertingkat jika pencarian huruf lebih dati 1 pada deretnya.
Selain mencari posisi huruf rumus FIND juga dapat digunakan untuk mencari posisi sebuah kata. Misalnya dari deret kalimat "anda dan saya adalah adhwebsite.com" kita akan mencari teks "saya".
Hasil pencarian teks "saya" tersebut dengan menggunakan rumus FIND adalah 10. Angka tersebut merupakan posisi awal dari teks "saya" yaitu huruf "s".
Jika menggunakan rumus Excel SEARCH pada dua contoh tersebut maka hasilnya akan sama persis yaitu 1 serta 10.
Tapi sebenarnya ada perbedaan dan kita akan bahas terkait dengan ini pada bagian akhir artikel di bawah.
Syntax dan Argumen Rumus FIND
Selanjutnya mari kita bahas syntax serta argumen yang digunakan pada rumus FIND sebelum melihat contohnya.
Adapun syntax serta argumen pada rumus ini adalah sebagai berikut :
=FIND(find_text; within_text; [start_num])
- find_text : huruf, angka atau teks yang akan dicari
- within_text : deret angka atau teks sumber pencarian
- start_num : posisi awal pencarian teks tu huruf
Argumen find_text dan within_text keduanya tidak bersifat opsional sehingga wajib untuk diisi dan tidak boleh dikosongkan.
Sedangkan untuk argumen start_num sifatnya hanya opsional dan boleh untuk dikosongkan. Jika dikosongkan maka pencarian akan diawali dari posisi angka 1.
Berikut ini adalah beberapa hal penting yang harus diketahui sebelum menggunakan rumus FIND :
- Rumus FIND bersifat case sensitif artinya rumus ini membedakan huruf besar serta huruf kecil pada proses pencarian
- Pada rumus FIND tidak bisa menggunakan wildcard
- Jika teks yang dicari tidak ada pada deretnya maka akan muncul error atau pesan kesalahan #VALUE!
- Argumen start_num hanya bisa diisi oleh angka positif saja dan jika diisi dengan angka negatif akan muncul error #VALUE!
- Argumen start_num digunakan untuk mencari posisi teks atau huruf ke-2, ke-3 dan seterusnya
Bagian yang sangat penting adalah rumus FIND akan membedakan huruf besar serta huruf kecil pada proses pencarian.
Misalnya pada deret kalimat huruf yang akan di cari adalah "e" ketika kita ketik huruf "E" pada rumus FIND maka akan muncul error #VALUE!.
Contoh dan Cara Menggunakan Rumus Excel FIND
Cara menggunakan rumus FIND dalam Excel sebenarnya tidak terlalu sulit karena hanya menyisipkan teks, huruf atau angka yang akan dicari serta deret teksnya.
Selanjutnya untuk contoh rumus Excel FIND kita akan bagi kedalam beberapa bagian sesuai dengan fungsinya masing – masing.
Selain menggunakan rumus Excel FIND pada contoh dibawah akan menggabungkan dengan rumus Excel lainnya.
1. Rumus Excel FIND Pada Teks dan Angka
Contoh pertama kita akan menggunakan rumus Excel FIND pada teks serta angka. Pencarian ini bisa dilakukan pada satu huruf atau beberapa huruf secara langsung.
Silahkan perhatikan gambar berikut ini :
Pada contoh ini sudah ada deret angka serta teks. Selanjutnya kita akan mencari posisi beberapa teks serta angka menggunakan rumus Excel FIND.
Contoh pertama kita akan mencari teks "artikel" dari kalimat "adhwebsite.com menulis artikel tentang Excel" dan rumusnya adalah sebagai berikut :
=FIND("artikel";A4)
Hasil dari rumus pada contoh pertama ini adalah 24. Angka ini merupakan posisi awal pada kalimat "artikel" khususnya huruf "a".
Contoh kedua kita akan mencari posisi dari teks "Excel" dari kalimat "Rumus Excel Web" dan rumusnya adalah sebagai berikut :
=FIND("Excel";A5)
Hasil dari contoh yang kedua adalah 7 dan tentu sama seperti pada contoh pertama bahwa angka tersebut merupakan posisi awal atau posisi huruf "E".
Contoh ketiga kita akan menggunakan rumus Excel FIND pada deret angka. Adhwebsite.com akan mencari posisi angka 4 dari deret 41542688 dan rumusnya adalah sebagai berikut :
=FIND(4;A6)
Hasil dari contoh ketiga ini akan mencari posisi angka 4 pada deret tersebut dan hasilnya adalah 1. Karena memang angka 4 pada deret tersebut ada 2.
Jika yang akan dicari adalah angka 4 dengan urutan ke-2 maka harus menggunakan rumus Excel FIND bertingkat.
Catatan Penting : jika memang hanya akan mencari posisi teks, angka atau symbol pada urutan pertama maka silahkan gunakan rumus FIND seperti pada contoh ini. Ingat, hasil yang muncul adalah posisi awal atau posisi pertama saja.
2. Rumus Excel FIND Bertingkat
Jika pernah mendengar istilah rumus FIND bertingkat maka mari membahasnya pada contoh yang kedua.
Apa itu rumus FIND bertingkat ?
Rumus FIND bertingkat adalah menambahkan rumus FIND itu sendiri pada argumen dengan tujuan untuk mencari posisi huruf, teks atau angka pada posisi selanjutnya.
Supaya lebih mudah memahami silahkan perhatikan gambar berikut ini :
Pada contoh tersebut sudah ada deret nama buah yang dipisahkan dengan koma serta spasi.
Jika akan mencari posisi koma atau spasi pertama maka kita cukup menggunakan rumus FIND seperti pada contoh pertama.
Tapi jika akan mencari posisi koma atau spasi kedua bukan pertama maka kita tidak akan bisa menggunakan rumus FIND seperti contoh pertama.
Mencari posisi koma atau spasi kedua, ketiga dan seterusnya inilah bisa dengan menggunakan rumus Excel FIND bertingkat.
Untuk pembanding, misalnya contoh pertama kita akan mencari posisi tanda koma pertama pada Cell E4 maka rumus FIND yang digunakan adalah sebagai berikut :
=FIND(",";A4)
Hasil dari rumus ini adalah 5 dan artinya posisi tanda koma adalah yang pertama atau awal.
Jika akan mencari posisi tanda koma kedua maka rumus FIND bertingkat yang digunakan pada Cell E5 adalah sebagai berikut :
=FIND(",";A5;FIND(",";A5)+1)
Dengan rumus ini posisi tanda koma yang ditampilkan atau dicari oleh rumus FIND adalah posisi ke dua yaitu 13.
Konsep pencarian tanda koma menggunakan rumus FIND bertingkat ini adalah sebagai berikut :
- Gunakan rumus FIND untuk mencari posisi tanda koma pertama
- Isi argumen start_number
- Pengisian argumen start_number menggunakan rumus pencarian koma pertama ditambah dengan angka 1
Untuk contoh silahkan perhatikan rumus Excel diatas pada Cell E5, yaitu sebagai berikut :
=FIND(",";A5;FIND(",";A5)+1)
Jika diubah kedalam bentuk angka hasil pencarian rumus FIND diatas adalah sebagai berikut :
=FIND(",";A5;5+1)
Angka 5 pada rumus diatas merupakan posisi dari tanda koma pertama seperti pada contoh yang sudah dijelaskan diatas.
Lalu, kenapa harus ditambah dengan angka 1 ?
Jika pencarian tanda koma berhenti di angka 5 maka secara otomatis yang akan dicari adalah posisi tanda koma pertama saja.
Jika ditambah dengan angka 1 maka tentu posisi yang akan dicari akan dimulai dari 6 dan ini akan mengarahkan pencarian ke posisi tanda koma kedua.
Lalu bagaimana jika yang akan dicari posisinya ada pada urutan ketiga ?
Untuk jawaban mudahnya adalah pada contoh ini posisi yang dicari ada di urutan kedua maka jumlah rumus FIND bertingkat ada 2.
Jadi, jika posisi yang akan dicari ada di urutan ke tiga maka jumlah rumus FIND yang digunakan juga tentu ada 3.
Untuk contoh rumus FIND bertingkat yang ke dua pada Cell E7 adalah sebagai berikut :
=FIND(" ";A7;FIND(" ";A7)+1)
Contoh kedua ini polanya sama dengan contoh pertama hanya saja yang akan dicari adalah spasi ke dua.
3. Rumus Excel FIND LEFT, RIGH dan MID
Contoh rumus FIND ketiga akan digabungkan dengan rumus lain yaitu LEFT, RIGHT serta MID.
Dalam Excel rumus LEFT digunakan untuk mencari atau memisahkan teks atau angka yang dimulai dari sebelah kiri.
Hampir sama dengan rumus LEFT, rumus RIGHT juga digunakan untuk memisahkan teks atau angka hanya saja posisi awalnya dimulai dari sebelah kanan.
Sedangkan rumus MID posisi pengambilan teks atau angka akan dimulai dari posisi tengah dan tentu konsepnya tetap mirip dengan kedua rumus diatas.
Untuk contoh gabungan rumus FIND dengan LEFT, RIGHT serta MID silahkan perhatikan gambar berikut ini :
Pada contoh tersebut sudah ada deret nomor seri dari barang dengan pemisah tanda strip serta jumlah digit yang berbeda – beda.
Jika deret seri tersebut disusun dengan jumlah urutan teks yang sama maka kita tidak perlu menambahkan rumus FIND tetapi cukup dengan LEFT, MID atau RIGHT saja.
Selanjutnya pada kolom C, D serta E kita sudah memisahkan tiga unsur nomor seri barang yaitu Kode, Warna serta Nomor.
Pertama kita akan pisahkan Kode barang dan rumus pada Cell C4 adalah sebagai berikut :
=LEFT(A4;FIND("-";A4)-1)
Pada contoh ini rumus FIND digunakan untuk mendeteksi posisi tanda strip pertama yang menjadi batas akhir dari jumlah digit dari kiri yang akan dipisahkan.
Selanjutnya rumus kedua pada Cell D4 kita akan memisahkan warna barang dengan jumlah digit yang berbeda. Rumusnya adalah sebagai berikut :
=MID(A4;FIND("-";A4)+1;FIND("-";A4;FIND("-";A4)+1)-(FIND("-";A4)+1))
Pada contoh ini rumus FIND juga digunakan untuk mencari posisi tanda strip yang memisahkan batas awal teks warna dengan batas akhir teks warna.
Selanjutnya contoh ketiga kita akan memisahkan nomor barang pada seri yang ada di posisi paling kanan.
Adapun rumus yang digunakan pada Cell E4 adalah sebagai berikut :
=RIGHT(A4;LEN(A4)-FIND("-";A4;FIND("-";A4)+1))
Konsep pada rumus ini sama dengan kedua rumus diatas hanya saja penghitungan jumlah digit teks atau angka yang akan diambil melibatkan rumus FIND dengan rumus LEN.
4. Rumus Excel IF FIND
Contoh berikutnya kita akan menambahkan rumus Excel FIND pada rumus Excel IF atau istilahnya kadang disebut dengan IF FIND.
Tentu ini juga memiliki tujuan tertentu seperti halnya pada contoh ke tiga yang sudah dijelaskan diatas.
Dalam Excel rumus IF dapat digunakan untuk menguji sebuah nilai logika dan akan menghasilkan value TRUE atau FALSE. Kedua value dari hasil rumus Excel IF tersebut bisa diubah sesuai dengan kebutuhan kita.
Silahkan perhatikan gambar berikut ini :
Pada contoh tersebut terdapat sebuah deret kalimat pada kolom A. Selanjutnya kita akan mencari teks "Excel" pada kalimat tersebut.
Contoh pertama kita hanya akan menggunakan rumus FIND saja untuk mencari posisi teks "Excel" pada kalimat. Rumus yang digunakan pada Cell C4 adalah sebagai berikut :
=FIND("Excel";A4)
Cara pertama ini memang bisa digunakan untuk mencari posisi teks "Excel" pada deret kalimat.
Hanya saja jika pada kalimat tidak muncul atau tidak mengandung teks "Excel" maka yang akan muncul adalah error #VALUE!.
Jika memang tidak ingin muncul error #VALUE! Maka mari gunakan cara kedua. Cara kedua ini akan menggabungkan rumus FIND dengan dua rumus lain yaitu IF serta ISNUMBER.
Adapun rumus yang digunakan pada Cell D4 adalah sebagai berikut :
=IF(ISNUMBER(FIND("Excel";A4));TRUE)
Dengan menggunakan rumus kedua ini memang error yang muncul pada pencarian teks bisa dihilangkan.
Hanya saja hasil tampilan dari rumus Excelnya bukan angka melainkan value TRUE atau FALSE seperti pada fungsi rumus IF yang dijelaskan diatas.
Selanjutnya contoh ketiga kita akan mengubah hasil pencarian rumus FIND yang biasanya adalah angka sesuai posisi teks kita akan ubah menjadi "Ada" atau "Tidak Ada".
Maksudnya jika pada kalimat memang ada teks "Excel" maka hasil yang muncul adalah "Ada". Sebaliknya jika tidak ditemukan teks "Excel" pada kalimat maka hasil yang akan tampil adalah "Tidak Ada".
Rumus yang digunakan pada Cell E4 adalah sebagai berikut :
=IF(ISNUMBER(FIND("Excel";A4));"Ada";"Tidak Ada")
Dengan menggunakan rumus ketiga ini hasilnya akan sesuai dengan kebutuhan yaitu teks "Ada" atau "Tidak Ada" pada pencarian.
5. Rumus Excel FIND REPLACE
Contoh terakhir kita akan menambahkan rumus FIND pada REPLACE. Dalam Excel rumus REPLACE dapat digunakan untuk mengubah teks tertentu sesuai dengan kebutuhan.
Untuk contohnya silahkan perhatikan gambar berikut ini :
Pada contoh tersebut sudah ada kalimat yang diketik pada kolom A. Masing – masing kalimat pada kolom tersebut mengandung kata "Fungsi" yang posisinya memang berbeda – beda.
Selanjutnya pada kolom C kita sudah membuat kalimat yang sama tetapi teks "Fungsi" pada kalimatnya diubah menjadi "Rumus".
Mengubah kalimat sesuai dengan kata tersebut tidak dilakukan dengan cara manual tetapi otomatis menggunakan rumus FIND REPLACE.
Untuk contoh rumus Excel yang digunakan pada Cell C4 adalah sebagai berikut :
=REPLACE(A4;FIND("Fungsi";A4);6;"Rumus")
Dengan menggunakan rumus ini maka secara otomatis teks atau kata "Fungsi" akan diganti dengan kata "Rumus".
Untuk posisi kata "Fungsi" juga tidak masalah ada di mana saja karena FIND akan menemukan posisinya terlebih dahulu baru kemudian rumus REPLACE mengubahnya dengan kata yang dimaksud.
Beda Rumus FIND Dengan SEARCH
Pada pembahasan diatas sudah dijelaskan bahwa fungsi rumus FIND memang sama persis dengan rumus SEARCH.
Bedanya hanya ada 2 saja yaitu pertama rumus Excel FIND membedakan pencarian menggunakan huruf besar atau huruf kecil. Sedangkan pada rumus SEARCH tidak membedakan jenis huruf.
Misalnya akan mencari huruf "e" dari kata "Excel" maka dengan menggunakan rumus FIND hasilnya adalah 4 atau huruf ke-4 sedangkan dengan rumus SEARCH hasilnya adalah 1.
Perbedaan kedua dari kedua rumus ini adalah pada rumus FIND tidak bisa menggunakan Wildcard sedangkan pada rumus SEARCH bisa.
Pilih Rumus FIND atau SEARCH ?
Dari contoh serta pembahasan tentu kita bisa memilih rumus mana yang akan digunakan pada proses pencarian.
Jika jenis huruf hampir dipastikan besar serta kecilnya dan tidak menggunakan Wildcard tentu lebih baik menggunakan rumus FIND.
Kecuali jika besar serta kecil huruf memang berbeda – beda dan cukup variatif rasanya akan lebih baik jika menggunakan rumus Excel SEARCH.
Kondisi tersebut akan sangat tergantung kepada jenis data yang sedang diolah dan silahkan sesuaikan.
Kesimpulan
Memahami rumus Excel FIND seharusnya tidak terbatas hanya pada bagaimana cara menggunakannya saja.
Karena setidaknya ada 3 hal penting yang perlu diketahui sebelum menggunakan rumus FIND, yaitu :
- Rumus Excel FIND dasarnya hanya akan mencari posisi huruf atau kata yang posisinya ada di awal saja
- Jika posisi huruf atau kata yang akan dicari ada di urutan ke-2 dan seterusnya maka perlu memilih menggunakan rumus FIND bertingkat
- Pada rumus FIND membedakan Case Sensitif serta tidak bisa menggunakan karakter Wildcard
Pastikan memahami ketiga hal penting diatas sebelum menggunakan rumus Excel FIND untuk menghindari munculnya kesalahan pada proses pencarian kata atau teks.
Itulah pembahasan kita kali ini tentang rumus Excel FIND dan semoga artikel ini bermanfaat untuk semua pembaca.
Post a Comment