Aplikasi Stok Barang Excel Sederhana Untuk Beberapa Lokasi Gudang

Adhwebsite.com menyusun contoh aplikasi stok barang Excel sederhana kedalam tiga jenis berdasarkan lokasi Gudang. Pertama adalah stok barang untuk 1 gudang, kedua untuk 2 Gudang dan ketiga untuk beberapa Gudang.

Masing - masing cara menghitung stok barang tersebut dilengkapi dengan contoh format serta cara pengisian mulai dari awal sampai dengan akhir. Konsep yang digunakan pada tiga perhitungan stok barang diatas memang tetap mirip bahkan rumusnya juga tidak terlalu jauh berbeda. Hanya saja dari sisi tampilan atau format memang akan cukup berbeda karena harus disesuaikan dengan lokasi Gudang yang digunakan.

Pada artikel ini kita akan bahas bagaimana cara menyusun format stok barang untuk beberapa Gudang. Jika kesulitan menyusun rumus Excel Stok Barang ini silahkan ambil contoh format yang disertakan dibagian bawah.

Format Aplikasi Stok Barang Excel Sederhana

Aplikasi Stok Barang Excel Sederhana untuk beberapa Gudang ini disusun tidak terlalu jauh berbeda dengan 2 pembahasan sebelumnya. Hanya saja memang tentu ada tambahan Sheet tertentu yang disusun pada jenis perhitungan ini.

Menghitung Stok Barang Dalam Excel Beberapa Gudang

Berikut ini adalah Sheet yang disusun pada aplikasi stok barang Excel sederhana untuk beberapa gudang :

Sheet Data : untuk input informasi serta data awal
Sheet Barang : untuk input data barang
Sheet Stok Awal : untuk input stok awal barang
Sheet In : untuk mencatat penerimaan barang
Sheet Out : untuk mencatat pengeluaran barang
Sheet Stok Barang : untuk menampilkan stok akhir barang di Gudang
Sheet Sampling Stok : untuk menampilkan form sampling jika akan dilakukan

Cara menghitung stok barang dalam Excel untuk beberapa Gudang ini menggunakan tambahan beberapa rumus didalamnya. Meskipun secara umum tetap saja menggunakan rumus Excel pada dua pembahasan sebelumnya.

Rumus Excel Aplikasi Stok Barang

Rumus Excel untuk menghitung stok barang dalam Excel rasanya tidak akan jauh berbeda dengan beberapa rumus yang sudah dibahas pada artikel sebelumnya. Hanya saja memang ada tambahan beberapa rumus pada aplikasi stok barang Excel sederhana untuk beberapa Gudang ini. Hal tersebut dikarenakan munculnya tambahan kriteria pada proses perhitungan.

Penambahan kriteria ini tentu akan mengubah urutan rumus yang digunakan karena tentu ini harus disesuaikan dengan kebutuhan. Berikut ini adalah beberapa rumus Excel yang digunakan pada perhitungan stok barang untuk beberapa Gudang :

Rumus Excel VLOOKUP
Rumus Excel IFERROR
Rumus Excel IF
Rumus Excel AND
Rumus Excel SUMIF
Rumus Excel SUMIFS
Rumus Excel SUM

Adhwebsite.com tidak akan menjelaskan satu persatu fungsi rumus tersebut karena nanti akan dibahas secara detail pada proses penyusunan format stok barang. Penyusunan stok barang akan dibagi kedalam beberapa tahapan mulai dari pengaturan format sampai dengan penggunaan rumus Excelnya.

Cara Membuat Aplikasi Stok Barang Excel Sederhana

Untuk menggunakan format stok barang Excel pada pembahasan ini bisa dipilih salah satu dari dua pilihan. Pertama mari membuatnya Bersama – sama sesuai dengan urutan format Excelnya dan kedua silahkan ambil contoh formatnya dibagian bawah artikel ini. Tapi sebaiknya mari membahas rumus Excel serta formatnya terlebih dahulu supaya benar – benar bisa memahami bagaimana urutan serta pola perhitungan stok barang yang disusun oleh adhwebsite.com

Tampilan aplikasi stok barang Excel sederhana untuk beberapa gudang adalah sebagai berikut :

Seperti yang terlihat pada contoh diatas bahwa format stok barang terdiri dari 7 Sheet mulai dari Sheet Data sampai dengan Sampling Stok. Untuk cara membuat format stok barang seperti contoh diatas mari kita bahas satu persatu mulai dari Sheet Data.

1. Sheet Data

Sheet ini digunakan untuk mencatat beberapa data awal perhitungan stok barang yang akan dilakukan. Ada 3 data yang wajib diinput pada bagian ini yaitu sebagai berikut :

Data Gudang : Lokasi Gudang yang digunakan untuk penyimpanan barang
Data Vendor : Kode, nama serta informasi lain terkait dengan Perusahaan rekanan tempat kita membeli barang
Data Customer : Kode, nama serta informasi lain terkait dengan Perusahaan atau Perorangan yang biasa membeli barang kepada kita

Tiga kolom utama pada masing – masing Tabel diatas wajib diisi yaitu kolom Kode, Nama dan Alamat. Pada sheet ini kita tidak akan menggunakan rumus Excel apapun karena memang tidak ada proses perhitungan dan hanya menampilkan data awal saja.

Tapi pada Sheet ini kita wajib membuat Nama Range atau Define Name untuk kolom Kode dari tiga Tabel diatas. Untuk contoh misalnya untuk Kode Gudang cara membuat Nama Range adalah sebagai berikut :

Blok Cell C7 sampai Cell C13
Klik Tab Formulas
Klik : Define Name
Pada kotak Name ketik : kode_gudang
Pada kotak Refers to pastikan sudah terisi dengan : =Data!$C$7:$C$13
Klik OK

Sampai dengan langkah ini kita sudah selesai membuat Nama Range untuk Kode Gudang dan nama yang akan digunakan adalah kode_gudang. Selanjutnya silahkan buat 2 nama range masing – masing untuk Kode Customer serta Kode Vendor. Untuk nama range dari kedua kolom tersebut pastikan dibuat kode_customer dan kode_vendor. Perhatikan, tiga nama range wajib ditulis seperti ini karena nanti akan digunakan pada rumus selanjutnya.

2. Sheet Barang

Sheet kedua yang akan kita atur formatnya adalah Barang. Sheet ini digunakan untuk mencatat seluruh Nama Barang yang akan disimpan di Gudang. Ada tiga kolom yang wajib diisi pada bagian ini yaitu kolom Kode Barang, Nama Barang dan Satuan.

Selanjutnya pada sheet ini kita juga tidak akan membuat rumus Excel tetapi akan membuat Nama Range dan langkahnya adalah sebagai berikut :

Blok Cell B6 sampai Cell B17
Klik Tab Formulas
Klik : Define Name
Pada kotak Name ketik : kode_barang
Pada kotak Refers to pastikan sudah terisi dengan : =Barang!$B$6:$B$17
Klik OK

Jika sudah selesai membuat nama range silahkan isi kolom barang sesuai dengan kodenya masing – masing.

3. Sheet Stok Awal

Dari Namanya tentu kita sudah mengetahui bahwa Sheet ini digunakan untuk mencatat stok awal barang di Gudang. Sheet ini terdiri dari 6 kolom yaitu No. Kode Gudang, Kode Barang, Nama Barang, Jumlah dan Satuan. Keenam kolom ini wajib untuk diisi seluruhnya. Pada sheet ini kita harus membuat Dropdown List atau daftar pilihan menu serta menambahkan rumus Excel.

Ada 2 kolom yang dibuatkan Dropdown List atau daftar pilihan menu yaitu kolom B dan kolom C. Misalnya pada langkah kita hanya akan bahas 1 saja yaitu Dropdown List pada kolom C atau kolom Kode Barang.

Menampilkan Kode Barang pada Dropdown list memang bisa dilakukan dengan menggunakan beberapa cara. Pada Sheet ini kita akan menggunakan Nama Range yang telah dibuat sebelumnya. Adapun langkah untuk membuat Dropdown List Kode Barang pada kolom C adalah sebagai berikut :

Blok Cell C6 sampai C16
Klik Tab Data
Klik : Data Validation
Klik Tab Setting
Klik kotak Allow kemudian pilih : List
Pada kotak Source ketik rumus : =kode_barang
Klik OK

Sampai dengan langkah ini kita sudah selesai menyusun Dropdown List untuk Kode Barang pada kolom C. Selanjutnya silahkan susun dropdown List untuk Kode Gudang atau kolom B. Langkahnya sama dengan urutan diatas hanya saja pada langkah keenam rumus yang digunakan adalah sebagai berikut :

=kode_gudang

Selanjutnya ada 2 rumus Excel yang harus dibuat pada Sheet ini yaitu untuk menampilkan Nama Barang pada kolom D dan menampilkan Satuan pada kolom F. Rumus yang digunakan pada Cell D6 untuk menampilkan nama berdasarkan kode barang adalah sebagai berikut :

=IFERROR(VLOOKUP(C6;Barang!$B$6:$D$16;2;0);"")

Sedangkan rumus yang digunakan pada Cell F6 untuk menampilkan Satuan Barang berdasarkan Kode adalah sebagai berikut :

=IFERROR(VLOOKUP(C6;Barang!$B$6:$D$16;3;0);"")

Dua rumus ini akan otomatis menampilkan Nama dan Satuan berdasarkan Kode Barang yang dipilih.

4. Sheet In

Sheet ke empat ini akan digunakan untuk mencatat penerimaan barang di Gudang atau istilahnya barang masuk. Pada Sheet ini kita harus menyusun 3 Dropdown List untuk kolom D, F serta H. Langkahnya sama dengan contoh diatas pastikan menggunakan nama range yang telah disusun sebelumnya.

Selanjutnya ada 4 rumus Excel yang harus dibuat pada Sheet ini yaitu untuk kolom E, G, I dan K. Adapun rumus Excel pada Cell E6 untuk menampilkan Lokasi Gudang berdasarkan Kode adalah sebagai berikut :

=IFERROR(VLOOKUP(D6;Data!$C$7:$G$12;2;0);"")

Rumus kedua pada Cell G6 untuk menampilkan Nama Vendor berdasarkan Kode adalah sebagai berikut :

=IFERROR(VLOOKUP(F6;Data!$C$18:$F$21;2;0);"")

Rumus ketiga pada Cell I6 untuk menampilkan Nama Barang berdasarkan Kode adalah sebagai berikut :

=IFERROR(VLOOKUP(H6;Barang!$B$6:$D$16;2;0);"")

Rumus terakhir pada Cell K6 untuk menampilkan Satuan berdasarkan Kode Barang adalah sebagai berikut :

=IFERROR(VLOOKUP(H6;Barang!$B$6:$D$16;3;0);"")

Pastikan sudah menyusun Dropdown List serta rumusnya seperti yang sudah dijelaskan diatas.

5. Sheet Out

Sheet kelima ini untuk mencatat pengeluaran barang atau barang keluar dari Gudang. Konsepnya sama dengan barang masuk hanya saja tentu sumber dokumen yang digunakan berbeda. Pengeluaran barang dari Gudang biasanya dilakukan untuk penjualan barang, retur pembelian, barang sampel atau pemusnahan barang. Pada sheet ini juga harus dibuatkan tiga Dropdown List masing- masing pada kolom D, F serta H sama seperti pada Sheet Out.

Selain itu pada Sheet ini juga harus dibuatkan rumus masing – masing pada kolom E, G, I dan K. Adapun rumus Excel pada ketiga kolom tersebut sama persis dengan rumus pada Sheet Out yang sudah dijelaskan diatas kecuali kolom G karena sumber datanya adalah dari Customer.

Jadi, rasanya adhwebsite tidak perlu menulis ulang karena rumusnya sama dengan Sheet keempat diatas.

6. Sheet Stok Barang

Ini merupakan Sheet utama pada perhitungan stok barang. Karena pada Sheet inilah akan ditampilkan stok akhir barang di Gudang sesuai dengan barang masuk serta barang keluar. Tidak ada proses input pada Sheet ini tetapi rumus yang digunakan sangat banyk bahkan dibagian kolom masing – masing ada rumusnya.

Pada Sheet ini 4 Dropdown List yang harus dibuat yaitu untuk Cell D5, D6, D7 dan kolom Kode Barang. Untuk Dropdown List Kode Barang pada kolom C dan pilihan Gudang langkahnya tidak akan dibahas karena sama persis seperti yang sudah dijelaskan pada Sheet sebelumnya.

Kecuali untuk Cell D5 dan D7 kita akan bahas cukup 1 saja yaitu untuk pilihan tampilan Gudang Cell D5, langkahnya adalah sebagai berikut :

Klik Cell D5
Klik Tab Data
Klik : Data Validation
Klik Tab Setting
Klik kotak Allow kemudian pilih : List
Pada kotak Source ketik : Semua;Pilihan Gudang
Klik OK

Selanjutnya silahkan buat Dropdown List untuk Cell D7 dengan pilihan "semua" serta "periode" langkahnya sama dengan contoh diatas. Sebelum membahas rumus Excel pastikan 4 Dropdown List sudah dibuat yaitu Cell D5, D6, D7 serta kolom Kode Barang. Rumus pertama pada Cell D13 untuk menampilkan Nama berdasarkan Kode Barang dan rumusnya adalah sebagai berikut :

=IFERROR(VLOOKUP(C13;Barang!$B$6:$D$16;2;0);"")

Rumus kedua pada Cell E13 untuk menampilkan Stok Awal sesuai dengan Kode Barang dan rumusnya adalah sebagai berikut :

=IF(AND($D$5="Semua";$D$7="Semua");SUMIF('Stok Awal'!$C$6:$C$16;'Stok Barang'!C13;'Stok Awal'!$E$6:$E$16);IF(AND($D$5="Semua";$D$7="Periode");SUMIF('Stok Awal'!$C$6:$C$16;'Stok Barang'!C13;'Stok Awal'!$E$6:$E$16)+SUMIFS(In!$J$6:$J$17;In!$H$6:$H$17;'Stok Barang'!C13;In!$C$6:$C$17;"<"&'Stok Barang'!$D$8);IF(AND($D$5="Pilih Gudang";$D$7="Semua");SUMIFS('Stok Awal'!$E$6:$E$16;'Stok Awal'!$C$6:$C$16;'Stok Barang'!C13;'Stok Awal'!$B$6:$B$16;'Stok Barang'!$D$6);IF(AND($D$5="Pilih Gudang";$D$7="Periode");SUMIFS('Stok Awal'!$E$6:$E$16;'Stok Awal'!$C$6:$C$16;'Stok Barang'!C13;'Stok Awal'!$B$6:$B$16;'Stok Barang'!$D$6)+SUMIFS(In!$J$6:$J$17;In!$H$6:$H$17;'Stok Barang'!C13;In!$D$6:$D$17;'Stok Barang'!$D$6;In!C6:C17;"<"&'Stok Barang'!$D$8);""))))

Rumus ketiga pada Cell F13 untuk menampilkan jumlah barang masuk sesuai dengan kriteria dan rumusnya adalah sebagai berikut :

=IF(AND($D$5="Semua";$D$7="Semua");SUMIF(In!$H$6:$H$17;'Stok Barang'!C13;In!$J$6:$J$17);IF(AND($D$5="Pilih Gudang";$D$7="Semua");SUMIFS(In!$J$6:$J$17;In!$H$6:$H$17;'Stok Barang'!C13;In!$D$6:$D$17;'Stok Barang'!$D$6);IF(AND($D$5="Semua";$D$7="Periode");SUMIF(In!$H$6:$H$17;'Stok Barang'!C13;In!$J$6:$J$17)-SUMIFS(In!$J$6:$J$17;In!$H$6:$H$17;'Stok Barang'!C13;In!$C$6:$C$17;"<"&'Stok Barang'!$D$8)-SUMIFS(In!$J$6:$J$17;In!$H$6:$H$17;'Stok Barang'!C13;In!$C$6:$C$17;">"&'Stok Barang'!$D$9);IF(AND($D$5="Pilih Gudang";$D$7="Periode");SUMIFS(In!$J$6:$J$17;In!$H$6:$H$17;'Stok Barang'!C13;In!$D$6:$D$17;'Stok Barang'!$D$6)-SUMIFS(In!$J$6:$J$17;In!$H$6:$H$17;'Stok Barang'!C13;In!$C$6:$C$17;"<"&'Stok Barang'!$D$8;In!$D$6:$D$17;'Stok Barang'!$D$6)-SUMIFS(In!$J$6:$J$17;In!$H$6:$H$17;'Stok Barang'!C13;In!$C$6:$C$17;">"&'Stok Barang'!$D$9;In!$D$6:$D$17;'Stok Barang'!$D$6);""))))

Rumus keempat pada Cell G13 untuk menampilkan jumlah barang keluar sesuai dengan kriteria dan rumusnya adalah sebagai berikut :

=IF(AND($D$5="Semua";$D$7="Semua");SUMIF(Out!$H$6:$H$21;'Stok Barang'!C13;Out!$J$6:$J$21);IF(AND($D$5="Pilih Gudang";$D$7="Semua");SUMIFS(Out!$J$6:$J$21;Out!$H$6:$H$21;'Stok Barang'!C13;Out!$D$6:$D$21;'Stok Barang'!$D$6);IF(AND($D$5="Semua";$D$7="Periode");SUMIF(Out!$H$6:$H$21;'Stok Barang'!C13;Out!$J$6:$J$21)-SUMIFS(Out!$J$6:$J$21;Out!$H$6:$H$21;'Stok Barang'!C13;Out!$C$6:$C$21;"<"&'Stok Barang'!$D$8)-SUMIFS(Out!$J$6:$J$21;Out!$H$6:$H$21;'Stok Barang'!C13;Out!$C$6:$C$21;">"&'Stok Barang'!$D$9);IF(AND($D$5="Pilih Gudang";$D$7="Periode");SUMIFS(Out!$J$6:$J$21;Out!$H$6:$H$21;'Stok Barang'!C13;Out!$D$6:$D$21;'Stok Barang'!$D$6)-SUMIFS(Out!$J$6:$J$21;Out!$H$6:$H$21;'Stok Barang'!C13;Out!$D$6:$D$21;'Stok Barang'!$D$6;Out!$C$6:$C$21;"<"&'Stok Barang'!$D$8)-SUMIFS(Out!$J$6:$J$21;Out!$H$6:$H$21;'Stok Barang'!C13;Out!$D$6:$D$21;'Stok Barang'!$D$6;Out!$C$6:$C$21;">"&'Stok Barang'!$D$9);""))))

Rumus kelima pada Cell H13 untuk menghitung jumlah stok akhir berdasarkan stok awal, barang masuk serta barang keluar dan rumusnya adalah sebagai berikut :

=E13+F13-G13

Rumus keenam pada Cell I13 untuk menampilkan Satuan berdasarkan Kode Barang dan rumusnya adalah sebagai berikut :

=IF(H13>0;VLOOKUP(C13;Barang!$B$6:$D$16;3;0);"")

Sampai dengan ini seluruh rumus serta Dropdown List sudah selesai dibuat dan pastikan urutan serta konsepnya sama dengan penjelasan ini.

7. Sheet Sampling Stok

Sheet ini sebenarnya hanya tambahan saja dan tidak berpengaruh terhadap perhitungan stok barang. Adhwebsite.com tidak akan membahas rumusnya karena konsep yang digunakan pada Sheet ini sama persis seperti pada penjelasan Sheet Stok Barang.

Cara Pengisian Aplikasi Stok Barang Excel Sederhana Beberapa Gudang

Jika sudah membaca cara pengisian aplikasi stok barang Excel sederhana untuk 2 Gudang memang konsepnya sangat berbeda. Karena pada format ini input barang masuk serta barang keluar dilakukan pada Sheet yang berbeda seperti penjelasan diatas. Selanjutnya untuk pengisian format stok barang ini mari kita bahas satu persatu mulai dari Sheet Data Awal.

1. Isi Data Awal

Langkah pertama tentu saja adalah mengisi data – data awal mulai dari data lokasi Gudang sampai dengan data Customer.

Silahkan isi masing – masing Tabel pada Sheet ini dan pastikan sudah sesuai dengan judul kolomnya. Untuk jumlah digit Kode bisa disesuaikan dengan kebutuhan dan boleh mengubah urutan Kode yang digunakan pada contoh format adhwebsite.com.

2. Isi Data Barang

Setelah mengisi data awal selanjutnya silahkan isi data barang dan bagian penting pada langkah ini adalah pastikan sudah mengisi kolom Kode Barang.

Tiga kolom pada Tabel ini wajib untuk diisi yaitu kolom Kode Barang, Nama Barang serta kolom Satuan. Karena tiga kolom tersebut akan digunakan pada kolom Sheet lain sesuai dengan rumus yang sudah dibuat.

3. Isi Stok Awal

Langkah ketiga adalah mengisi stok awal barang di Gudang. Langkah ini bisa diabaikan jika memang pencatatan barang di Gudang tidak memiliki Stok Awal. Kolom pada Sheet ini seluruhnya wajib untuk diisi dan tidak boleh dikosongkan kecuali jika memang tidak ada stok awal seperti yang disebutkan diatas.

Adapun urutan langkah pengisian Stok Awal pada Sheet ini adalah sebagai berikut :

Klik Cell pada kolom Kode Gudang kemudian pilih Lokasi Gudangnya
Klik Cell pada kolom Kode Barang kemudian pilih dan pada kolom Nama serta Satuan akan otomatis terisi
Ketik jumlah stok awal barang pada kolom E

Sampai dengan langkah ketiga diatas kita sudah selesai mengisi Stok Awal barang di Gudang sesuai dengan Kodenya masing – masing.

4. Isi Penerimaan Barang

Pengisian format stok barang selanjutnya adalah penerimaan. Secara umum dokumen yang digunakan pada Sheet ini sumbernya adalah dari pembelian barang. Memang ada sumber penerimaan barang lain yang juga bisa dicatat pada sheet ini misalnya retur atas penjualan barang.

Adapun urutan pengisian pada Sheet ini adalah sebagai berikut :

Ketik nomor bukti atau nomor urut penerimaan barang
Isi tanggal sesuai dengan hari barang diterima
Pilih Kode Gudang
Pilih Kode Vendor
Pilih Kode Barang
Ketik jumlah barang masuk pada kolom J

Sampai dengan langkah ini maka barang yang sumbernya dari pembelian sudah kita catat dan akan masuk kedalam penerimaan barang.

5. Isi Pengeluaran Barang

Sheet Out akan diisi dengan pengeluaran barang atau barang keluar dari Gudang sesuai dengan dokumen yang diterima. Sumber pengeluaran yang paling umum terjadi pada Perusahaan tentu saja adalah dari proses Penjualan Barang.

Adapun urutan pengisian barang keluar adalah sebagai berikut :

Ketik nomor bukti atau nomor urut pengeluaran barang
Isi tanggal sesuai dengan hari barang keluar
Pilih Kode Gudang
Pilih Kode Customer
Pilih Kode Barang
Ketik jumlah barang keluar pada kolom J

Sampai dengan ini maka barang keluar atau pengeluaran barang dari Gudang sudah selesai dilakukan.

6. Pilih Kriteria Stok Akhir Barang

Sheet ini akan menampilkan stok akhir barang di Gudang sesuai dengan barang masuk serta barang keluar setiap hari. Langkah pertama pada pengisian Sheet ini adalah silahkan klik Cell kolom Kode Barang dan tampilkan seluruh barang pada kolom ini.

Jika seluruh Kode Barang sudah ditampilkan pada kolom ini maka langkah kedua ada lakukan Filter tampilan stok barang pada kotak paling atas. Berikut ini adalah urutan pengaturan filter pilihan stok barangnya :

Klik Cell D5, jika stok akhir akan ditampilkan seluruh Gudang maka klik "Semua" sedangkan jika hanya akan menampilkan satu Gudang saja maka klik "Pilih Gudang"
Jika pilihan pada Cell D5 adalah "Pilih Gudang" maka pada Cell D6 silahkan klik Kode Gudang sedangkan jika pilihan pada Cell D5 adalah "Semua" maka silahkan abaikan Cell D6
Jika perhitungan stok akan dilakukan dari awal sampai akhir pada silahkan klik Cell D7 kemudian pilih "Semua" sedangkan jika akan menampilkan stok hanya periode tertentu saja silahkan pilih "Periode"
Jika pada Cell D7 yang dipilih adalah "Periode" maka silahkan isi Cell D8 dengan tanggal awal serta Cell D9 dengan tanggal akhir

Setelah melakukan filter data diatas maka secara otomatis stok barang akan dihitung sesuai dengan pilihan pada kotak paling atas.

7. Pilih Kriteria Sampling Stok

Seperti yang disebutkan diatas bahwa Sheet ini hanya tambahan saja dan jika tidak diperlukan silahkan skip atau abaikan. Proses pengaturan filter stok barang pada Sheet ini sama persis seperti pengaturan filter pada Sheet Stok Barang yang sudah dijelaskan diatas.

File Excel Aplikasi Stok Barang

Jika tidak ingin repot menyusun format stok barang seperti yang dijelaskan diatas silahkan ambil saja format stok barang melalui link yang disertakan dibawah. Contoh format Excel stok barang ini akan diupdate kedalam beberapa perubahan dan jika link sudah terpasang maka artinya proses update sudah selesai. Tetapi jika link belum terpasang artinya proses update belum selesai atau proses upload masih dalam proses, mohon maklum.

1. Aplikasi Stok Barang Beberapa Gudang v1

Nama File : Stok Barang Beberapa Gudang v1
Ukuran :
Format : .xlsx
Password : adhwebsite.com
Link : Stok Barang

2. Aplikasi Stok Barang Beberapa Gudang v2

Pada stok barang beberapa Gudang telah dilakukan update atau perubahan pada unsur berikut ini :

Tambahan Konversi Multi Satuan
Tambahan Validasi Input Data
Tambahan Rumus Mencegah Stok Minus

Link contoh format stok barang adalah sebagai berikut :

Nama File : Stok Barang Beberapa Gudang v2
Ukuran :
Format : .xlsx
Link : On Progress Update

Kesimpulan

Penyusunan format stok barang memang bisa dilakukan sesuai dengan kebutuhan. Ini tentu akan mengikuti kebijakan yang diatur oleh Perusahaan. Adhwebsite.com hanya menawarkan beberapa format Excel saja untuk menghitung stok di Gudang.

Jika konsepnya sudah cocok silahkan gunakan sepenuhnya dan sebaliknya jika kurang cocok silahkan update sampai dengan formatnya sesuai. Itulah pembahasan kita kali ini tentang cara menghitung stok barang untuk beberapa Gudang dan semoga artikel ini bermanfaat untuk semua pembaca.